Types of Strings in Groovy

1. Overview

In this tutorial, we’ll take a closer look at the several types of strings in Groovy, including single-quoted, double-quoted, triple-quoted, and slashy strings.

We’ll also explore Groovy’s string support for special characters, multi-line, regex, escaping, and variable interpolation.

2. Enhancing java.lang.String

It’s probably good to begin by stating that since Groovy is based on Java, it has all of Java’s String capabilities like concatenation, the String API, and the inherent benefits of the String constant pool because of that.

Let’s first see how Groovy extends some of these basics.

2.1. String Concatenation

String concatenation is just a combination of two strings:

def first = 'first'
def second = "second"        
def concatenation = first + second
assertEquals('firstsecond', concatenation)

Where Groovy builds on this is with its several other string types, which we’ll take a look at in a moment. Note that we can concatenate each type interchangeably.

2.2. String Interpolation

Now, Java offers some very basic templating through printf, but Groovy goes deeper, offering string interpolation, the process of templating strings with variables:

def name = "Kacper"
def result = "Hello ${name}!"
assertEquals("Hello Kacper!", result.toString())

While Groovy supports concatenation for all its string types, it only provides interpolation for certain types.

2.3. GString

But hidden in this example is a little wrinkle – why are we calling toString()?

Actually, result isn’t of type String, even if it looks like it.

Because the String class is final, Groovy’s string class that supports interpolation, GString, doesn’t subclass it. In other words, for Groovy to provide this enhancement, it has its own string class, GString, which can’t extend from String.

Simply put, if we did:

assertEquals("Hello Kacper!", result)

this invokes assertEquals(Object, Object), and we get:

java.lang.AssertionError: expected: java.lang.String<Hello Kacper!>
  but was: org.codehaus.groovy.runtime.GStringImpl<Hello Kacper!>
Expected :java.lang.String<Hello Kacper!> 
Actual   :org.codehaus.groovy.runtime.GStringImpl<Hello Kacper!>

3. Single-Quoted String

Probably the simplest string in Groovy is one with single quotes:

def example = 'Hello world'

Under the hood, these are just plain old Java Strings, and they come in handy when we need to have quotes inside of our string.

Instead of:

def hardToRead = "Kacper loves \"Lord of the Rings\""

We can easily concatenate one string with another:

def easyToRead = 'Kacper loves "Lord of the Rings"'

Because we can interchange quote types like this, it reduces the need to escape quotes.

4. Triple Single-Quote String

A triple single-quote string is helpful in the context of defining multi-line contents.

For example, let’s say we have some JSON to represent as a string:

{
    "name": "John",
    "age": 20,
    "birthDate": null
}

We don’t need to resort to concatenation and explicit newline characters to represent this.

Instead, let’s use a triple single-quoted string:

def jsonContent = '''
{
    "name": "John",
    "age": 20,
    "birthDate": null
}
'''

Groovy stores this as a simple Java String and adds the needed concatenation and newlines for us.

There is one challenge yet to overcome, though.

Typically for code readability, we indent our code:

def triple = '''
    firstline
    secondline
'''

But triple single-quote strings preserve whitespace. This means that the above string is really:

(newline)
    firstline(newline)
    secondline(newline)

not:

like perhaps we intended.

Stay tuned to see how we get rid of them.

4.1. Newline Character

Let’s confirm that our previous string starts with a newline character:

assertTrue(triple.startsWith("\n"))

It’s possible to strip that character. To prevent this, we need to put a single backslash \ as a first and last character:

def triple = '''\
    firstline
    secondline
'''

Now, we at least have:

One problem down, one more to go.

4.2. Strip the Code Indentation

Next, let’s take care of the indentation. We want to keep our formatting, but remove unnecessary whitespace characters.

The Groovy String API comes to the rescue!

To remove leading spaces on every line of our string, we can use one of the Groovy default methods, String#stripIndent():

def triple = '''\
    firstline
    secondline'''.stripIndent()
assertEquals("firstline\nsecondline", triple)

Please note, that by moving the ticks up a line, we’ve also removed a trailing newline character. 

4.3. Relative Indentation

We should remember that stripIndent is not called stripWhitespace.

stripIndent determines the amount of indentation from the shortened, non-whitespace line in the string.

So, let’s change the indentation quite a bit for our triple variable:

class TripleSingleQuotedString {

    @Test
    void 'triple single quoted with multiline string with last line with only whitespaces'() {
        def triple = '''\
            firstline
                secondline\
        '''.stripIndent()

        // ... use triple
    }
}

Printing triple would show us:

firstline
    secondline

Since firstline is the least-indented non-whitespace line, it becomes zero-indented with secondline still indented relative to it.

Note also that this time, we are removing the trailing whitespace with a slash, like we saw earlier.

4.4. Strip with stripMargin()

For even more control, we can tell Groovy right where to start the line by using a | and stripMargin:

def triple = '''\
    |firstline
    |secondline'''.stripMargin()

Which would display:

firstline
secondline

The pipe states where that line of the string really starts.

Also, we can pass a Character or CharSequence as an argument to stripMargin with our custom delimiter character.

Great, we got rid of all unnecessary whitespace, and our string contains only what we want!

4.5. Escaping Special Characters

With all the upsides of the triple single-quote string, there is a natural consequence of needing to escape single quotes and backslashes that are part of our string. 

To represent special characters, we also need to escape them with a backslash. The most common special characters are a newline (\n) and tabulation (\t).

For example:

def specialCharacters = '''hello \'John\'. This is backslash - \\ \nSecond line starts here'''

will result in:

hello 'John'. This is backslash - \
Second line starts here

There are a few we need to remember, namely:

• \t – tabulation
• \n – newline
• \b – backspace
• \r – carriage return
• \\ – backslash
• \f – formfeed
• \’ – single quote

5. Double-Quoted String

While double-quoted strings are also just Java Strings, their special power is interpolation. When a double-quoted string contains interpolation characters, Groovy switches out the Java String for a GString.

5.1. GString and Lazy Evaluation

We can interpolate a double-quoted string by surrounding expressions with ${} or with $ for dotted expressions.

Its evaluation is lazy, though – it won’t be converted to a String until it is passed to a method that requires a String:

def 'String ang GString'() {
    given:
    def string = "example"
    def stringWithExpression = "example${2}"

    expect:
    string instanceof String
    stringWithExpression instanceof GString
    stringWithExpression.toString() instanceof String
}

5.2. Placeholder with Reference to a Variable

The first thing we probably want to do with interpolation is send it a variable reference:

def 'placeholder with variable'() {
    given:
    def name = "John"

    when:
    def helloName = "Hello $name!".toString()

    then:
    helloName == "Hello John!"
}

5.2. Placeholder with an Expression

But, we can also give it expressions:

def 'placeholder with expression'() {
    given:
    def result = "result is ${2 * 2}".toString()

    expect:
    result == "result is 4"
}

We can put even statements into placeholders, but it’s considered as bad practice.

5.3. Placeholders with the Dot Operator

We can even walk object hierarchies in our strings:

def 'placeholder with dotted access'() {
    given:
    def person = [name: 'John']

    when:
    def myNameIs = "I'm $person.name, and you?".toString()

    then:
    myNameIs == "I'm John, and you?"
}

With getters, Groovy can usually infer the property name.

But if we call a method directly, we’ll need to use ${} because of the parentheses:

def 'placeholder with method call'() {
    given:
    def name = 'John'

    when:
    def result = "Uppercase name: ${name.toUpperCase()}".toString()

    then:
    result == "Uppercase name: JOHN"
}

5.4. hashCode in GString and String

Interpolated strings are certainly godsends in comparison to plain java.util.String, but they differ in an important way.

See, Java Strings are immutable, and so calling hashCode on a given string always returns the same value.

But, GString hashcodes can vary since the String representation depends on the interpolated values.

And actually, even for the same resulting string, they won’t have the same hash codes:

def 'GString and String hashcode'() {
    given:
    def string = "2+2 is 4"
    def gstring = "2+2 is ${4}"

    expect:
    string.hashCode() != gstring.hashCode()
}

Thus, we should never use GString as a key in a Map!

6. Triple Double-Quote String

So, we’ve seen triple single-quote strings, and we’ve seen double-quoted strings.

Let’s combine the power of both to get the best of both worlds – multi-line string interpolation:

def name = "John"
def multiLine = """
    I'm $name.
    "This is quotation from 'War and Peace'"
"""

Also, notice that we didn’t have to escape single or double-quotes!

7. Slashy String

Now, let’s say that we are doing something with a regular expression, and we are thus escaping backslashes all over the place:

def pattern = "\\d{1,3}\\s\\w+\\s\\w+\\\\\\w+"

It’s clearly a mess.

To help with this, Groovy supports regex natively via slashy strings:

def pattern = /\d{3}\s\w+\s\w+\\\w+/
assertTrue("3 Blind Mice\Men".matches(pattern))

Slashy strings may be both interpolated and multi-line:

def name = 'John'
def example = /
    Dear ([A-Z]+),
    Love, $name
/

Of course, we have to escape forward slashes:

def pattern = /.*foobar.*\/hello.*/

And we can’t represent an empty string with Slashy String since the compiler understands // as a comment:

// if ('' == //) {
//     println("I can't compile")
// }

8. Dollar-Slashy String

Slashy strings are great, though it’s a bummer to have to escape the forward slash. To avoid additional escaping of a forward slash, we can use a dollar-slashy string. 

Let’s assume that we have a regex pattern: [0-3]+/[0-3]+. It’s a good candidate for dollar-slashy string because in a slashy string, we would have to write: [0-3]+//[0-3]+.

Dollar-slashy strings are multiline GStrings that open with $/ and close with /$. To escape a dollar or forward slash, we can precede it with the dollar sign ($), but it’s not necessary.

We don’t need to escape $ in GString placeholder.

For example:

def name = "John"

def dollarSlashy = $/
    Hello $name!,

    I can show you a $ sign or an escaped dollar sign: $$ 
    Both slashes work: \ or /, but we can still escape it: $/
            
    We have to escape opening and closing delimiters:
    - $$$/  
    - $/$$
 /$

would output:

Hello John!,

I can show you a $ sign or an escaped dollar sign: $ 
Both slashes work: \ or /, but we can still escape it: /

We have to escape opening and closing delimiter:
- $/  
- /$

9. Character

Those familiar with Java have already wondered what Groovy did with characters since it uses single quotes for strings.

Actually, Groovy doesn’t have an explicit character literal.

There are three ways to make a Groovy string an actual character:

• explicit use of ‘char’ keyword when declaring a variable
• using ‘as’ operator
• by casting to ‘char’

Let’s take a look at them all:

def 'character'() {
    given:
    char a = 'A' as char
    char b = 'B' as char
    char c = (char) 'C'

    expect:
    a instanceof Character
    b instanceof Character
    c instanceof Character
}

The first way is very convenient when we want to keep the character as a variable. The other two methods are more interesting when we want to pass a character as an argument to a function.

10. Summary

Obviously, that was a lot, so let’s quickly summarize some key points:

• strings created with a single quote (‘) do not support interpolation
• slashy and tripled double-quote strings can be multi-line
• multi-line strings contain whitespace characters due to code indentation
• backslash (\) is used to escape special characters in every type, except dollar-slashy string, where we must use dollar ($) to escape

11. Conclusion

In this article, we discussed many ways to create a string in Groovy and its support for multi-lines, interpolation, and regex.

And for more information about features of the Groovy language itself, get a good start with our introduction to Groovy Language.